logo
Apache Lounge
Webmasters

 


About

Forum Index Downloads Search Register Log in  RSS Apache Lounge
 


Keep Server Online

If you find the Apache Lounge, the downloads and overall help useful, please express your satisfaction with a donation.

or

Bitcoin

A donation makes a contribution towards the costs, the time and effort that's going in this site and building.

Thank You! Steffen

Apache Lounge is not sponsored.

Your donations will help to keep this site alive and well, and continuing building binaries.



Apache 2.2.9 command line build with the Windows 2008 SDK

 
Post new topic   Reply to topic    Apache Forum Index -> Apache Building & Member Downloads



View previous topic :: View next topic  
Author Message
tdonovan
Moderator


Joined: 17 Dec 2005
Posts: 610
Location: Milford, MA, USA

PostPosted: Fri 04 Jul '08 20:29    Post subject: Apache 2.2.9 command line build with the Windows 2008 SDK Reply with quote

The latest Windows SDK, Windows SDK for Windows Server 2008 and .NET Framework 3.5, contains a command-line compiler suitable for building Apache 2.2.9 on Windows XP or later.

Despite the '2008' name - this freely available SDK is appropriate to use on Windows Server 2003, Windows Server 2008, Windows Vista, and Windows XP.

This SDK contains the Visual C++ 2008 command-line compiler (a.k.a. VC9), the MASM assembler, and the Windows libraries needed to build Apache.

If you will be frequently building or debugging Apache, you might consider using the full Visual Studio 2008 IDE rather than using these command-line tools.

Here are the steps to build Apache 2.2.9 with OpenSSL 0.9.8h and Zlib 1.2.3 using the VC9 command-line compiler in this SDK:

TOOLS NEEDED TO BUILDSETUP THE BUILD ENVIRONMENT
    Open a command window and set up the development environment:
    Code:
    "C:\Program Files\Microsoft Visual Studio 9.0\VC\bin\vcvars32.bat"
    Add Perl and the GNU utilities to your PATH environment variable:
    Code:
    PATH=%PATH%;C:\Program Files\GnuWin32\bin;C:\Perl\bin
DOWNLOAD THE SOURCE CODE
    Download and extract the Apache version 2.2.9 Windows source (not the Unix source):
    Code:
    WGET http://www.apache.org/dist/httpd/httpd-2.2.9-win32-src.zip

    Open httpd-2.2.9-win32-src.zip and extract it, creating a httpd-2.2.9 directory

    Download and extract the Zlib version 1.2.3 source into httpd-2.2.9\srclib\zlib:
    Code:
    CD   httpd-2.2.9\srclib
    WGET http://www.zlib.net/zlib-1.2.3.tar.gz
    GZIP -d  zlib-1.2.3.tar.gz
    TAR  xf  zlib-1.2.3.tar
    RENAME   zlib-1.2.3   zlib

    Download and extract the OpenSSL version 0.9.8h source, into httpd-2.2.9\srclib\openssl:
    Code:
    CD   httpd-2.2.9\srclib
    WGET http://www.openssl.org/source/openssl-0.9.8h.tar.gz
    GZIP -d  openssl-0.9.8h.tar.gz
    TAR  xf  openssl-0.9.8h.tar
    RENAME   openssl-0.9.8h   openssl
BUILD Zlib
    Code:
    CD  httpd-2.2.9\srclib\zlib
    ML /coff /Zi /c contrib\masm686\match.asm
    NMAKE -f win32\Makefile.msc  LOC="-D_CRT_SECURE_NO_DEPRECATE /wd4996 -DASMV" OBJA="match.obj"
    MT -manifest zlib1.dll.manifest -outputresource:zlib1.dll;2
BUILD OpenSSL
    Quote:
    For OpenSSL version 0.9.8h ONLY
    Edit the file httpd-2.2.9\srclib\openssl\crypto\perlasm\x86ms.pl and remove line 273. Line 273 contains the single word "$extra". This is a known problem with OpenSSL 0.9.8h, and should be fixed in future versions. ref: OpenSSL bug 1681, described here and here
    Code:
    CD  httpd-2.2.9\srclib\openssl
    PERL Configure VC-WIN32  enable-camellia  disable-idea
    ms\do_masm
    NMAKE -f ms\ntdll.mak
BUILD and INSTALL Apache
    Code:
    CD  httpd-2.2.9
    NMAKE -f Makefile.win installr
    This installs Apache 2.2.9 into C:\Apache22
APACHE SSL
    You can create a self-signed certificate for testing SSL using this OpenSSL command:
    Code:
    CD  C:\Apache22\bin
    OPENSSL.exe req -new -x509 -nodes -extensions v3_req -days 365 -config ..\conf\openssl.cnf -out ..\conf\server.crt -keyout ..\conf\server.key
    Be sure to edit C:\Apache22\conf\extra\httpd-ssl.conf and set ServerName to the same name that you entered at the prompt "Common Name (eg, YOUR name) []:". This should be your system name as you will use it in a URL like https://system_name/
TRIMMING APACHE FOR PRODUCTION USE
    As installed, C:\Apache22 is approximately 86mb.
      * The .pdb files are used for debugging and DrWatson stack traces. You can remove them saving over 60mb.
      * The \include and \lib directories are only needed to compile and link additional modules. You can remove them saving about 7mb.
      * The \manual directory is only used if httpd.conf includes conf/extra/httpd-manual.conf. You can remove it saving about 9mb.
    These steps will reduce the size of C:\Apache22 to approximately 8mb.

    If you copy Apache to another machine, remember to install the "Microsoft Visual C++ 2008 Redistributable Package" before running it.
DEBUGGING APACHE
    If you need to run Apache under a debugger to diagnose a problem, you can use the freely available Windows WinDbg debugger.

    Install "Debugging Tools for Windows" from the [Start] menu: [Microsoft Windows SDK] [Install Debugging Tools for Windows]
    -or- Download it from: http://www.microsoft.com/whdc/devtools/debugging/installx86.Mspx and install it.

    Create and install an Apache DEBUG build instead of a RELEASE build with:
    Code:
    CD  httpd-2.2.9
    NMAKE -f Makefile.win installd

    Start the debugger "C:\Program Files\Debugging Tools for Windows (x86)\WINDBG.exe"
    Quote:
    [File] [Symbol File Path ...]
    SRV*C:\WINDOWS\symbols*http://msdl.microsoft.com/download/symbols

    [File] [Open Executable]
    C:\Apache22\bin\httpd.exe
    Arguments: -X
    Start directory: C:\Apache22\bin

    [File] [Open Source File]
    Choose any Apache .c source file that you want to debug

    [View] [Locals]
    [View] [Call stack]
    [Window] [Dock All]
    Re-arrange the windows as convenient
    Use F9 to set breakpoints
    Use F5 to Start Apache, or to Resume execution of Apache after a breakpoint
    Use F10 to step through lines of code after hitting a breakpoint
    When you get the error:"Debug Assertion Failed!" - "Invalid file descriptor. File possibly closed by a different thread." - choose [Ignore].
    This is a harmless error which only occurs in Debug builds.

Hope this is helpful. I submitted a shorter version to the httpd wiki.

-tom-
Back to top
Mitron



Joined: 04 Jan 2006
Posts: 63

PostPosted: Sun 17 Aug '08 9:48    Post subject: GUI_APACHE.BAT Reply with quote

Awesome Tom,

That works well. In fact, I got a litle bored so I sat down and turned this into a batch file that kind of automates the process and updates the apr, apr-iconv and apr-util as well.

I haven't quite figured out the pcre compile part yet, but I left a spot for it to add later. I'd also like to figure out how to add mod_log_rotate to this as the apxs solution on the authors site doesn't seem to work. The apxs command he has posted produces 26 error LNK2019 messages and falls short of creating the needed .so file. I suspect this might be due to the Math::BigInt: error that pops up when apxs is compiled.

In any case this is a huge time saver for me so I thought I'd share. Smile

TO USE:
    Create a work folder at the root of a secondary partition, second drive or C:\ if nothing else is available. For this example we will assume this to be C:\work
    Copy and paste the code below into Notepad or Notepad++ and save it as C:\work\gui_apache.bat
    Edit lines 5 and 6 to replace with your actual paths to GnuWin32 and Perl bin folders as well as the location where you want Apache installed on line 11, then save the file.
    OPTIONAL: If version or revision numbers are updated for httpd, apr, openssl, etc. lines 15-30 can be modified to reflect those changes.
    OPTIONAL: If you want to customize Apache at build time edit line 124 to change ports, domain name, etc.
    OPTIONAL: If you want to create a SSL certificate after the build process, remove the @REM at the begining of lines 127 and 128.
    Open a Visual Studio command prompt and change to your work folder, i.e. CD C:\work then execute the batch file gui_apache.bat
    Once the files are retrieved and decompressed the script will pause allowing you to edit x86ms.pl to remove line 273 and save the file before continuing the process. Leave the script at the pause and open My Computer or Windows Explorer to browse to the correct location and make your changes.
    Once changes are made and files are saved, return to the command prompt and hit a key to continue building and installing Apache.
    If the @REM was removed from lines 127 and 128 prompts will appear asking for certificate information. Follow the prompts to create your SSL certificate and your done. Now edit httpd.conf to enable modules and complete your configuration.
Code:
@REM PRESERVE ORIGINAL PATH
@SET PTH_ORG=%PATH%

@REM SET GNUWIN32 AND PERL PATH
@SET GNU_PTH=C:\Program Files\GnuWin32\bin
@SET PRL_PTH=C:\Perl\bin

@SET PATH=%PTH_ORG%;%GNU_PTH%;%PRL_PTH%

@REM SET APACHE INSTALL PATH
@SET HPD_PTH="C:\Apache2"

@REM SET VERSION NUMBERS FOR HTTPD AND SCRLIB APPS
@REM SET HTTPD VERSION
@SET HPD_VSN=2.2.9
@REM SET APR VERSION
@SET APR_VSN=1.3.3
@REM SET APR-ICONV VERSION
@SET API_VSN=1.2.1
@REM SET APR-UTIL VERSION
@SET APU_VSN=1.3.4
@REM SET OPENSSL VERSION
@SET OPS_VSN=0.9.8h
@REM SET PCRE VERSION
@REM SET PCR_VSN=7.7
@REM SET ZLIB VERSION
@SET ZLB_VSN=1.2.3

@REM SET APR-ICONV RELEASE
@SET API_RVN=-r2

@REM GET APACHE SOURCE
@REM REQUIRES VS2008, PERL, GNUWIN32 GTAR - GZIP - WGET - GAWK - UNZIP
if not exist .\httpd-%HPD_VSN% goto UZHTTPD
@RENAME http-%HPD_VSN% http-%HPD_VSN%.old
:UZHTTPD
WGET http://www.apache.org/dist/httpd/httpd-%HPD_VSN%-win32-src.zip
UNZIP httpd-%HPD_VSN%-win32-src -d .\
@DEL .\httpd-%HPD_VSN%-win32-src.zip

@REM UPDATE APR
@CD .\httpd-%HPD_VSN%\srclib
@RENAME apr apr.old
WGET http://www.apache.org/dist/apr/apr-%APR_VSN%-win32-src.zip
UNZIP apr-%APR_VSN%-win32-src -d .\
@RENAME apr-%APR_VSN% apr
@DEL .\apr-%APR_VSN%-win32-src.zip

@REM UPDATE APR-ICONV
@RENAME apr-iconv apr-iconv.old
WGET http://www.apache.org/dist/apr/apr-iconv-%API_VSN%-win32-src%API_RVN%.zip
UNZIP apr-iconv-%API_VSN%-win32-src%API_RVN% -d .\
@RENAME apr-iconv-%API_VSN% apr-iconv
@DEL .\apr-iconv-%API_VSN%-win32-src%API_RVN%.zip

@REM UPDATE APR-UTIL
@RENAME apr-util apr-util.old
WGET http://www.apache.org/dist/apr/apr-util-%APU_VSN%-win32-src.zip
UNZIP apr-util-%APU_VSN%-win32-src -d .\
@RENAME apr-util-%APU_VSN% apr-util
@DEL .\apr-util-%APU_VSN%-win32-src.zip

@REM UPDATE OPENSSL SOURCE
WGET http://www.openssl.org/source/openssl-%OPS_VSN%.tar.gz
GZIP -d openssl-%OPS_VSN%.tar.gz
TAR xf openssl-%OPS_VSN%.tar
@RENAME openssl-%OPS_VSN% openssl
@DEL .\openssl-%OPS_VSN%.tar

@REM UPDATE PCRE
@REM RENAME pcre pcre.old
@REM WGET http://internap.dl.sourceforge.net/sourceforge/pcre/pcre-%PCR_VSN%.tar.gz
@REM GZIP -d pcre-%PCR_VSN%.tar.gz
@REM TAR xf pcre-%PCR_VSN%.tar
@REM @RENAME pcre-%PCR_VSN% pcre
@REM @DEL .\pcre-%PCR_VSN%.tar

@REM GET ZLIB SOURCE
WGET http://www.zlib.net/zlib-%ZLB_VSN%.tar.gz
GZIP -d zlib-%ZLB_VSN%.tar.gz
TAR   xf zlib-%ZLB_VSN%.tar
@RENAME zlib-%ZLB_VSN% zlib
@DEL .\zlib-%ZLB_VSN%.tar

@REM DISPLAY INSTRUCTIONS AND PAUSE
@ECHO .---------------------------------------------------.
@ECHO Please delete line 273 in
@ECHO httpd-2.2.9\scrlib\openssl\crypto\perlasm\x86ms.pl
@ECHO and make any other necessary changes before building.
@ECHO .---------------------------------------------------.

@PAUSE

@REM COMPILE APR SOURCE
@REM NOT NECESSARY

@REM COMPILE APR-ICONV SOURCE
@REM NOT NECESSARY

@REM COMPILE APR-UTIL SOURCE
@REM NOT NECESSARY

@REM COMPILE OPENSSL SOURCE
@CD  .\openssl
PERL Configure VC-WIN32  enable-camellia  disable-idea
@REM HAVE TO DO A CALL HERE OR SCRIPT WILL HALT
@CALL ms\do_masm
NMAKE -f ms\ntdll.mak

@REM COMPILE PCRE SOURCE
@REM TO DO

@REM COMPILE ZLIB SOURCE
@CD ..\zlib
ML /coff /Zi /c contrib\masm686\match.asm
NMAKE -f win32\Makefile.msc  LOC="-D_CRT_SECURE_NO_DEPRECATE /wd4996 -DASMV" OBJA="match.obj"
MT -manifest zlib1.dll.manifest -outputresource:zlib1.dll;2

@REM INSTALL APACHE
@CD  ..\..\
@REM THE COMMAND BELOW DOES NOT CURRENTLY WORK AS-IS
@REM  PROVIDED AS AN EXAMPLE OF A FULL COMMAND STRING
@REM NMAKE -f Makefile.win INSTDIR=%HPD_PTH% PORT=80 SSLPORT=443 DOMAINNAME=yoursite.com SERVERNAME=www.yoursite.com SERVERADMIN=admin@yoursite.com DBD_LIST="sqlite3 pgsql oracle mysql freetds" installr
NMAKE -f Makefile.win INSTDIR=%HPD_PTH% PORT=80 SSLPORT=443 DOMAINNAME=example.com SERVERNAME=www.example.com SERVERADMIN=admin@example.com installr

@REM UNCOMMENT THE NEXT THREE LINES TO SET OPENSSL CERT
@REM CD %HPD_PTH%\bin
@REM OPENSSL.exe req -new -x509 -nodes -extensions v3_req -days 365 -config ..\conf\openssl.cnf -out ..\conf\server.crt -keyout ..\conf\server.key

@REM RESTORE ORIGINAL PATH
@SET PATH=%PTH_ORG%

TO DO:
As mentioned earlier, I would still like to add the ability to update/build PCRE and the mod_log_rotate module to make this somewhat more complete for my purposes. I may also add a clean up option as mentioned in Tom's post to clean up *.pdb and others.

MORE NOTES:
Line 123 is an example of a full command line with all options, however the DBD_LIST option requires additional libraries and will fail as is. I tried it with just the mysql option listed and it fails attempting to find mysql.h. This may be something else to add at a later time.

This file was tested on Windows XP Pro with Microsoft Visual Studio 2008 Express Edition, Microsoft SDK and the GnuWin32 tools. The resulting binaries were also tested and seemed to work on the same setup. I haven't tested everything but so far so good. Smile

Enjoy
Back to top
tdonovan
Moderator


Joined: 17 Dec 2005
Posts: 610
Location: Milford, MA, USA

PostPosted: Sun 17 Aug '08 17:57    Post subject: Reply with quote

The ODBC driver is always built on Windows. No DBD_LIST is needed to get ODBC.

To build the other drivers, you must (of course) have the appropriate database installed on your system, and also add a few extra items to your semicolon-separated INCLUDE and LIB environment variables before you build Apache:
    * for MySQL
      find the directory which contains mysql.h and add it to your INCLUDE variable,
        e.g. SET INCLUDE=%INCLUDE%;C:\Mysql\include
      find the directory which contains libmysql.lib and add it to you LIB variable,
        e.g. SET LIB=%LIB%;C:\Mysql\lib\opt
      add "mysql" to the space-separated DBD_LIST

    * for PostgreSQL
      find the directory which contains libpq-fe.h and add it to your INCLUDE variable,
        e.g. SET INCLUDE=%INCLUDE%;C:\Program Files\PostgreSQL\8.3\include
      find the directory which contains libpq.lib and add it to you LIB variable,
        e.g. SET LIB=%LIB%;C:\Program Files\PostgreSQL\8.3\lib
      add "pgsql" to the space-separated DBD_LIST

    * for SQLite3
      find the directory which contains sqlite3.h and add it to your INCLUDE variable,
        e.g. SET INCLUDE=%INCLUDE%;C:\SQLite
      find the directory which contains sqlite3.lib and add it to you LIB variable,
        e.g. SET LIB=%LIB%;C:\SQLite
      add "sqlite3" to the space-separated DBD_LIST

    * for Oracle
      find the directory which contains oci.h and add it to your INCLUDE variable,
        e.g. SET INCLUDE=%INCLUDE%;C:\oraclexe\app\oracle\product\10.2.0\server\OCI\include
      find the directory which contains oci.lib and add it to you LIB variable,
        e.g. SET LIB=%LIB%;C:\oraclexe\app\oracle\product\10.2.0\server\OCI\lib\MSVC
      add "oracle" to the space-separated DBD_LIST

When you configure httpd.conf, remember to load the runtime .dll for your database (using forward slashes) before the DBDriver directive:
    * for MySQL
      LoadFile "C:/Mysql/lib/opt/libmysql.dll"
      DBDriver mysql

    * for PostgreSQL
      LoadFile "C:/Program Files/PostgreSQL/8.3/bin/libpq.dll"
      DBDriver pgsql

    * for SQLite3
      LoadFile "C:/SQLite/sqlite3.dll"
      DBDriver sqlite3

    * for Oracle
      LoadFile "C:/oraclexe/app/oracle/product/10.2.0/server/BIN/oci.dll"
      DBDriver oracle

The FreeTDS (a Unix ODBC replacement for SQLServer) and SQLite2 (an old version of SQLite) drivers really don't make much sense on Windows.

-tom-


Last edited by tdonovan on Sun 17 Aug '08 18:36; edited 1 time in total
Back to top
tdonovan
Moderator


Joined: 17 Dec 2005
Posts: 610
Location: Milford, MA, USA

PostPosted: Sun 17 Aug '08 18:35    Post subject: Reply with quote

mod_log_rotate builds fine for me using apxs from the Apache Lounge download page:
Code:
REM compile
C:\Apache2\bin\apxs.bat  -c  mod_log_rotate.c  libhttpd.lib libapr-1.lib libaprutil-1.lib
REM install
C:\Apache2\bin\apxs.bat  -i  mod_log_rotate.la
I wouldn't suggest combining it with your Apache-building .bat file because mod_log_rotate is a 3rd-party module, not a regular ASF-supplied module.

-tom-
Back to top
Mitron



Joined: 04 Jan 2006
Posts: 63

PostPosted: Mon 18 Aug '08 1:53    Post subject: Reply with quote

tdonovan wrote:
The ODBC driver is always built on Windows. No DBD_LIST is needed to get ODBC.

Yeah, sorry I must have missed this post: http://www.apachelounge.com/viewtopic.php?t=2604

tdonovan wrote:
When you configure httpd.conf, remember to load the runtime .dll for your database (using forward slashes) before the DBDriver directive:

Do you still need to do this if your system LIB variable is already set with those paths? Just curious.
As for the DBD_LIST option, if you want to adjust the batch file to include this option, open gui_apache.bat and add the following to the file:

FIND
Code:
@SET PTH_ORG=%PATH%

AFTER ADD
Code:
@SET INC_ORG=%INCLUDE%
@SET LIB_ORG=%LIB%

FIND
Code:
@SET PRL_PTH=C:\Perl\bin

AFTER ADD
Code:

@REM SET INCLUDE AND LIB PATHS FOR DBD SUPPORT
@SET DBD_LST=

@SET MYS_INC=
IF NOT EXISTS C:\Mysql\include GOTO SKIPMYS
@SET MYS_INC=;C:\Mysql\include

@SET MYS_LIB=
IF NOT EXISTS C:\Mysql\lib\opt GOTO SKIPMYS
@SET MYS_LIB=;C:\Mysql\lib\opt

@SET DBD_LST=mysql

:SKIPMYS
@SET PGS_INC=
IF NOT EXIST C:\Program Files\PostgreSQL\8.3\include GOTO SKIPPGS
@SET PGS_INC=;C:\Program Files\PostgreSQL\8.3\include

@SET PGS_LIB=
IF NOT EXIST C:\Program Files\PostgreSQL\8.3\lib GOTO SKIPPGS
@SET PGS_LIB=;C:\Program Files\PostgreSQL\8.3\lib

IF %DBD_LST% == "" GOTO SKPSPCA
@SET DBD_LST=%DBD_LST% pgsql
GOTO SKIPPGS

:SKPSPCA
@SET DBD_LST=pgsql

:SKIPPGS
@SET SLT_INC=
IF NOT EXIST C:\SQLite GOTO SKIPSLT
@SET SLT_INC=;C:\SQLite

@SET SLT_LIB=
IF NOT EXIST C:\SQLite  GOTO SKIPSLT
@SET SLT_LIB=;C:\SQLite

IF %DBD_LST% == "" GOTO SKPSPCB
@SET DBD_LST=%DBD_LST% sqlite3
GOTO SKIPSLT

:SKPSPCB
@SET DBD_LST=sqlite3

:SKIPSLT
@SET ORL_INC=
IF NOT EXIST C:\oraclexe\app\oracle\product\10.2.0\server\OCI\include GOTO SKIPORL
@SET ORL_INC=;C:\oraclexe\app\oracle\product\10.2.0\server\OCI\include

@SET ORL_LIB=
IF NOT EXIST C:\oraclexe\app\oracle\product\10.2.0\server\OCI\lib\MSVC GOTO SKIPORL
@SET ORL_LIB=;C:\oraclexe\app\oracle\product\10.2.0\server\OCI\lib\MSVC

IF %DBD_LST% == "" GOTO SKPSPCC
@SET DBD_LST=%DBD_LST% oracle
GOTO SKIPORL

:SKPSPCC
@SET DBD_LST=oracle

:SKIPORL

FIND
Code:
@SET PATH=%PTH_ORG%;%GNU_PTH%;%PRL_PTH%

ADD AFTER
Code:
@SET INCLUDE=%INC_ORG%%MYS_INC%%PGS_INC%%SLT_INC%%ORL_INC%
@SET LIB=%LIB_ORG%%MYS_LIB%%PGS_LIB%%SLT_LIB%%ORL_LIB%

Then simply uncomment the following and comment out or remove the next line:

FIND
Code:
@REM NMAKE -f Makefile.win INSTDIR=%HPD_PTH% PORT=80 SSLPORT=443 DOMAINNAME=yoursite.com SERVERNAME=www.yoursite.com SERVERADMIN=admin@yoursite.com DBD_LIST="sqlite3 pgsql oracle mysql freetds" installr

REPLACE WITH
Code:
NMAKE -f Makefile.win INSTDIR=%HPD_PTH% PORT=80 SSLPORT=443 DOMAINNAME=yoursite.com SERVERNAME=www.yoursite.com SERVERADMIN=admin@yoursite.com DBD_LIST="%DBD_LST%" installr

FIND
Code:
NMAKE -f Makefile.win INSTDIR=%HPD_PTH% PORT=80 SSLPORT=443 DOMAINNAME=example.com SERVERNAME=www.example.com SERVERADMIN=admin@example.com installr

REPLACE WITH
Code:
@REM NMAKE -f Makefile.win INSTDIR=%HPD_PTH% PORT=80 SSLPORT=443 DOMAINNAME=example.com SERVERNAME=www.example.com SERVERADMIN=admin@example.com installr

FIND
Code:
@SET PATH=%PTH_ORG%

ADD AFTER
Code:
@SET INCLUDE=%INC_ORG%
@SET LIB=%LIB_ORG%

NOTE: In order for this to work one or more of the database paths must exist or the build will fail. Be sure to adjust them to match your configuration.

tdonovan wrote:
mod_log_rotate builds fine for me using apxs from the Apache Lounge download page:

Hmm, well that's the apxs file I'm useing. Attempted to build it with:
Code:
perl Configure.pl --with-apache2=path\to\my\apache --with-apache-prog=httpd.exe

which seems to build despite the warning, but building mod_log_rotate.c with
Code:
apxs.bat -i -a -c mod_log_rotate.c

as posted didn't work. I'll give your command a shot and see what happens.

tdonovan wrote:
I wouldn't suggest combining it with your Apache-building .bat file because mod_log_rotate is a 3rd-party module, not a regular ASF-supplied module.

Yeah, I wouldn't post that as part of this anyway since I'm having issues with apxs and that would have to be built as well. Maybe I'll write a separate one for that once I figure out why it isn't working here. I guess PCRE is all that's left. Smile Appreciate the insight.
Back to top


Post new topic   Reply to topic    Apache Forum Index -> Apache Building & Member Downloads
Page 1 of 1